#
SWISH::Filter - Perl extension for filtering documents with Swish-e

[ TOC ]

# SYNOPSIS

      use SWISH::Filter;

      # load available filters into memory
      my $filter = SWISH::Filter->new;

      # convert a document

      my $doc = $filter->convert(
            document     => \$scalar_ref,  # path or ref to a doc
            content_type => $content_type, # content type if doc reference
            name         => $real_path,    # optional name for this file (useful for debugging)
            user_data    => $whatever,     # optional data to make available to filters
       );

      return unless $doc;  # empty doc, zero size, or no filters installed

      # Was the document converted by a filter?
      my $was_filtered = $doc->was_filtered;

      # Skip if the file is not text
      return if $doc->is_binary;

      # Print out the doc
      my $doc_ref = $doc->fetch_doc;
      print $$doc_ref;

      # Fetch the final content type of the document
      my $content_type = $doc->content_type;

      # Fetch Swish-e parser type (TXT*, XML*, HTML*, or undefined)
      my $doc_type = $doc->swish_parser_type;

[ TOC ]

# DESCRIPTION

SWISH::Filter provides a unified way to convert documents into a type that Swish-e can index. Individual filters are installed as separate perl modules. For example, there might be a filter that converts from PDF format to HTML format.

Note that this is just a framework for filtering documents. Additional helper programs or Perl module may need to be installed to use SWISH::Filter to filter documents. For example, to filter PDF documents you must install the Xpdf package.

The filters are automatically loaded when `SWISH::Filters->new()` is called. Filters define a type and priority that determines the processing order of the filter. Filters are processed in this sort order until a filter accepts the document for filtering. The filter uses the document's content type to determine if the filter should handle the current document. The content-type is determined by the files suffix if not supplied by the calling program.

The individual filters are not designed to be used as separate modules. All access to the filters is through this SWISH::Filter module.

Normally, once a document is filtered processing stops. Filters can filter the document and then set a flag saying that filtering should continue (for example a filter that uncompresses a MS Word document before passing on to the filter that converts from MS Word to text). All this should be transparent to the end user. So, filters can be pipe-lined.

The idea of SWISH::Filter is that new filters can be created, and then downloaded and installed to provide new filtering capabilities. For example, if you needed to index MS Excel documents you might be able to download a filter from the Swish-e site and magically next time you run indexing MS Excel docs would be indexed.

The SWISH::Filter setup can be used with -S prog or -S http. It works best with the -S prog method because the filter modules only need to be loaded and compiled one time. The -S prog program spider.pl will automatically use SWISH::Filter when spidering with default settings (using "default" as the first parameter to spider.pl).

The -S http indexing method uses a Perl helper script called swishspider. swishspider has been updated to work with SWISH::Filter, but (unlike spider.pl) does not contain a "use lib" line to point to the location of SWISH::Filter. This means that by default swishspider will not use SWISH::Filter for filtering. The reason for this is because swishspider runs for every URL fetched, and loading the Filters for each document can be slow. The recommended way of spidering is using -S prog with spider.pl, but if -S http is desired the way to enable SWISH::Filter is to set PERL5LIB before running swish so that swishspider will be able to locate the SWISH::Filter module. Here's one way to set the PERL5LIB with the bash shell:

      $ export PERL5LIB=`swish-filter-test -path`

[ TOC ]

# METHODS

$filter = SWISH::Filter->new()

  This creates a SWISH::Filter object. You may pass in options as a list or a hash reference.

[ TOC ]

## SWISH::Filter->new Options

There is currently only one option that can be passed in to `new():`

ignore_filters

  Pass in a reference to a list of filter names to ignore. For example, if you have two filters installed "Pdf2HTML" and "Pdf2XML" and want to avoid using "Pdf2XML":

          my $filter = SWISH::Filter->new( ignore_filters => ['Pdf2XML'];

$doc_object = $filter->convert();

  This method filters a document. Returns an object of the class SWISH::Filter::document or undefined if passed in an empty document, a filename that cannot be read off disk, or if no filters have been loaded.

  SWISH::Filter::document methods listed below can be called on the object to, for example, check if the document was filtered and to fetch the document content (filtered or not).

  You must pass in a hash (or hash reference) of parameters to the `convert()` method. The possible parameters are:

  document

    This can be either a path to a file, or a scalar reference to a document in memory. This is required.

  content_type

    The MIME type of the document. This is only required when passing in a scalar reference to a document. The content type string is what the filters use to match a document type.

    When passing in a file name and content_type is not set, then the content type will be determined from the file's extension by using the MIME::Types Perl module (available on CPAN).

  name

    Optional name to pass in to filters that will be used in error and warning messages.

  user_data

    Optional data structure that all filters may access. This can be fetched in a filter by:

            my $user_data = $doc_object->user_data;

    And used in the filter as:

            if ( ref $user_data && $user_data->{pdf2html}{title} ) {
               ...
            }

    It's up to the filter author to use a unique first-level hash key for a given filter.

  Example of using the `convert()` method:

          $doc_object = $filter->convert(
              document     => $doc_ref,
              content-type => 'application/pdf',
          );

$filter->mywarn()

  Internal function used for writing warning messages to STDERR if $ENV{FILTER_DEBUG} is set. Set the environment variable FILTER_DEBUG before running to see extra messages while processing.

@filters = $filter->filter_list;

  Returns a list of filter objects installed.

@filter = $filter->can_filter( $content_type );

  This is useful for testing to see if a mimetype might be handled by SWISH::Filter wihtout having to pass in a document. Helpful if doing HEAD requests.

  Returns an array of filters that can handle this type of document

  # WRITING FILTERS

  Filters are standard perl modules that are installed into the SWISH::Filters name space. Filters are not complicated -- see the existing filters for examples.

  Each filter defines the content-types (or mimetypes) that it can handle. These are specified as a list of regular expressions to match against the document's content-type. If one of the mimetypes of a filter match the incoming document's content-type the filter is called. The filter can then either filter the content or return undefined indicating that it decided not to filter the document for some reason. If the document is converted the filter returns either a reference to a scalar of the content or a file name where the content is stored. The filter also must change the content-type of the document to reflect the new document.

  Filters typically use external programs or modules to do that actual work of converting a document from one type to another. For example, programs in the Xpdf packages are used for converting PDF files. The filter can (and should) test for those programs in its `new()` method.

  Filters also can define a type and priority. These attributes are used to set the order filters are tested for a content-type match. This allows you to have more than one filter that can work on the same content-type.

  If a filter calls `die()` then the filter is removed from the chain and will not be called again during the same run. Calling die when running with -S http or -S fs has no effect since the program is run once per document.

  Once a filter returns something other than undef no more filters will be called. If the filter calls $filter->set_continue then processing will continue as if the file was not filtered. For example, a filter can uncompress data and then set $filter->set_continue and let other filters process the document.

  This is the list of methods the filter should or may define (as specificed):

  new() * required *

    This method returns either an object which provides access to the filter, or undefined if the filter is not to be used.

    The `new()` method is a good place to check for required modules or helper programs. Returning undefined prevents the filter from being included in the filter chain.

    The new method must return a blessed hash reference. The only required attribute is mimetypes. This attribute must contain a reference to an array of regular expressions used for matching the content-type of the document passed in.

    Example:

            sub new {
                my ( $class ) = @_;

                # List of regular expressions
                my @mimetypes = (
                    qr[application/(x-)?msword],
                    qr[application/worddoc],
                );

                my %settings = (
                    mimetypes   => \@mimetypes,

                    # Optional settings
                    priority    => 20,
                    type        => 2,
                );

                return bless \%settings, $class;
            }

    The attribute "mimetypes" returns an array reference to a list of regular expressions. Those patterns are matched against each document's content type.

  filter() * required *

    This is the function that does the work of converting a document from one content type to another. The function is passed the document object. See document object methods listed below for what methods may be called on a document.

    The function can return undefined (or any false value) to indicate that the filter did not want to process the document. Other filters will then be tested for a content type match.

    If the document is filtered then the filter must set the new document's content type (if it changed) and return either a file name where the document can be found or a reference to a scalar containing the document.

  type()

    Returns a number. Filters are sorted (for processing in a specific order) and this number is simply the primary key used in sorting. If not specified the filter's type used for sorting is 2.

    This is an optional method. You can also set the type in your `new()` constructor as shown above.

  priority()

    Returns a number. Filters are sorted (for processing in a specific order) and this number is simply the secondary key used in sorting. If not specified the filter's priority is 50.

    This is an optional method. You can also set the priority in your `new()` constructor as shown above.

  Again, the point of the `type()` and `priority()` methods is to allow setting the sort order of the filters. Useful if you have two filters for filtering the same content-type, but prefer to use one over the other. Neither are required.

  Here's a module to convert MS Word documents using the program "catdoc":

          package SWISH::Filters::Doc2txt;
          use vars qw/ $VERSION /;

          $VERSION = '0.02';

          sub new {
              my ( $class ) = @_;

              my $self = bless {
                  mimetypes   => [ qr!application/(x-)?msword! ],
                  priority    => 50,
              }, $class;

              # check for helpers
              return $self->set_programs( 'catdoc' );

          }

          sub filter {
              my ( $self, $doc ) = @_;

              my $content = $self->run_catdoc( $doc->fetch_filename ) || return;

              # update the document's content type
              $filter->set_content_type( 'text/plain' );

              # return the document
              return \$content;
          }
          1;

  The `new()` constructor creates a blessed hash which contains an array reference of mimetypes patterns that this filter accepts. The priority sets this filter to run after any other filters that might handle the same type of content. The set_programs() function says that we need to call a program called "catdoc". The function either returns `$self` or undefined if catdoc could not be found. The set_programs() function creates a new method for running catdoc.

  The filter function runs catdoc passing in the name of the file (if the file is in memory a temporary file is created). That run_catdoc() function was created by the set_programs() call above.

  # SWISH::Filter::document Methods

  These methods are available to Filter authors, and also provide access to the document after calling the `convert()` method to end-users of SWISH::Filter.

  End users of SWISH::Filter will use a subset of these methods. Mostly:

         $doc_object->fetch_doc      # and alias for fetch_document_reference()
         $doc_object->was_filtered   # true the document was filtered
         $doc_object->content_type   # document's current content type (mime type)
         $doc_object->swish_parser_type # returns a parser type to use with Swish-e -S prog method
         $doc_object->is_binary      # returns $content_type !~ m[^text/];

  These methods are also available to the individual filter modules. The filter's "filter" function is also passed a SWISH::Filter::document object. Method calls may be made on this object to check the document's current content type, or to fetch the document as either a file name or a reference to a scalar containing the document content.

  ## Methods used by end-users and filter authors

  $doc_ref = $doc_object->fetch_doc_reference;

    Returns a scalar reference to the document. This can be used when the filter can operate on the document in memory (or if an external program expects the input to be from standard input).

    If the file is currently on disk then it will be read into memory. If the file was stored in a temporary file on disk the file will be deleted once read into memory. The file will be read in binmode if $doc->is_binary is true.

    Note that $doc_object->fetch_doc is an alias.

  $was_filtered = $doc_object->was_filtered

    Returns true if some filter processed the document

  $content_type = $doc_object->content_type;

    Fetches the current content type for the document.

    Example:

            return unless $filter->content_type =~ m!application/pdf!;

  $type = $doc_object->swish_parser_type

    Returns a parser type based on the content type

  $doc_object->is_binary

    Returns true if the document's content-type does not match "text/".

  ## Methods used by filter authors

  $file_name = $doc_object->fetch_filename;

    Returns a path to the document as stored on disk. This name can be passed to external programs (e.g. catdoc) that expect input as a file name.

    If the document is currently in memory then a temporary file will be created. Do not expect the file name passed to be the real path of the document.

    The file will be written in binmode if $doc->is_binary is true.

    This method is not normally used by end-users of SWISH::Filter.

  $doc_object->set_continue;

    Processing will continue to the next filter if this is set to a true value. This should be set for filters that change encodings or uncompress documents.

  $doc_object->set_content_type( $type );

    Sets the content type for a document.

  $doc_object->name

    Fetches the name of the current file. This is useful for printing out the name of the file in an error message. This is the name passed in to the SWISH::Filter->convert method. It is optional and thus may not always be set.

            my $name = $doc_object->name || 'Unknown name';
            warn "File '$name': failed to convert -- file may be corrupt\n";

  $doc_object->user_data

    Fetches the the user_data passed in to the filter. This can be any data or data structure passed into SWISH::Filter->new.

    This is an easy way to pass special parameters into your filters.

    Example:

            my $data = $doc_object->user_data;
            # see if a choice for the <title> was passed in
            if ( ref $data eq 'HASH' && $data->{pdf2html}{title_field}  {
               ...
               ...
            }

    # SWISH::Filters::_BASE

    Each filter is a subclass of SWISH::Filters::_BASE. A number of methods are available by default (and some can be overridden). Others are useful when writing your `new()` constructor.

    $self->type

      This method fetches the type of the filter. The value returned sets the primary sort key for sorting the filters. You can override this in your filter, or just set it as an attribute in your object. The default is 2.

      The idea of the "type" is to create groups of filters, if needed. For example, you might have a set of filters that are used for uncompressing some documents before passing on to another group for filtering.

    $self->priority

      This method fetches the priority of the filter. The value returned sets the secondary sort key for sorting the filters. You can override this in your filter, or just set it as an attribute in your object. The default method returns 50.

      The priority is useful if you have multiple filters for the same content type that use different methods for filtering (say one uses wvWare and another uses catdoc for filtering MS Word files). You might give the wvWare filter a lower priority number so it runs before the catdoc filter if both wvWare AND catdoc happen to be installed at the same time.

    @types = $self->mimetypes

      Returns the list of mimetypes (as regular expressions) set for the filter.

    $pattern = $self->can_filter_mimetype( $content_type )

      Returns true if passed in content type matches one of the filter's mimetypes Returns the pattern that matched.

    mywarn( $message )

      method for printing out message if debugging is available

    $boolean = $self->set_programs( @program_list );

      Returns true if all the programs listed in `@program_list` are found and can be executed as the current user. Creates a method for each program with the "run_" prefix. Returns false is ANY program cannot be found.

      Actually, it returns $self, so you can make it the last statement in your constructor.

      So in your constructor you might do:

              return $self->set_programs( qw/ pdftotext pdfinfo / );

      Then in your `filter()` method:

              my $content = $self->run_pdfinfo( $doc->fetch_filename, [options] );

    $path = $self->find_binary( $prog );

      Use in a filter's `new()` method to test for a necesary program located in $PATH. Returns the path to the program or undefined if not found or does not pass the -x file test.

    $bool = $self->use_modules( @module_list );

      Attempts to load each of the module listed and calls its `import()` method.

      Use to test and load required modules within a filter without aborting.

              return unless $self->use_modules( qw/ Spreadsheet::ParseExcel  HTML::Entities / );

      A warning message is displayed if the FILTER_DEBUG environment variable is true. Returns `$self` if no error.

  $doc_ref = $self->run_program( $program, @args );

    Runs `$program` with @args. Must pass in @args.

    Under Windows calls IPC::Open2, which may pass data through the shell. Double-quotes are escaped (backslashed) and each parameter is wrapped in double-quotes.

    On other platforms a fork and exec is used to avoid passing any data through the shell. Returns a reference to a scalar containing the output from your program, or dies.

    This method is intended to read output from a program that converts one format into text. The output is read back in text mode -- on systems like Windows this means \r\n (CRLF) will be convertet to \n.

  # TESTING

  Filters can be tested with the swish-filter-test program. Run:

         swish-filter-test -man

  for documentation.

  # SUPPORT

  Please contact the Swish-e discussion list. http://swish-e.org

  # Bugs, todo items, and other notes

  TBD

  # AUTHOR

  Bill Moseley

  # COPYRIGHT

  This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

[ TOC ]